Поиск  Пользователи  Правила  Войти
Форумы "Планета Excel" » Вопросы по Microsoft Excel
Страницы: 1
RSS
Извлечение адреса ячейки, содержащегося в другой ячейке
 
#1
17.11.2023 20:30:03
Добрый день, всем!

Мне нужно извлечь содержащийся в ячейке адрес на искомую ячейку в таблице для использования этого адреса в формуле, подскажите пожалуйста, как это можно сделать?
 
 
 
#2
17.11.2023 20:41:12
=LOOKUP(99999;INDIRECT("D1:"&I2))

но в целом проще так, без промежуточных
=LOOKUP(2;1/($A$2:$A$11<=EOMONTH(F2;0))/($A$2:$A$11>=F2)/($D$2:$D$11<>"");$D$2:$D$11)
И там ошибка, в июле нет замеров..
По вопросам из тем форума, личку не читаю.
 
 
 
#3
17.11.2023 21:03:04
Цитата
написал:
=LOOKUP(99999;INDIRECT("D1:"&I2))
Спасибо большое, здорово, все работает!

А еще такой вопрос, можно ли скомбинировать эту формулу с возможностью отбирать последние данные за месяц в зависимости от выбранной категории в столбце С, то есть GM-1 или GM? например используя 2 критерия в просмотре и индекс?
 
 
 
#4
17.11.2023 23:08:07
Цитата
написал:
можно ли скомбинировать эту формулу с возможностью отбирать
Вариант в файле.Формула массива
Код
=ЕСЛИОШИБКА(ПРОСМОТР(99999;ЕСЛИ((МЕСЯЦ($A$1:$A$11)=МЕСЯЦ(F2))*($C$1:$C$11=$O$1)*$D$1:$D$11;$D$1:$D$11;""));"Нет данных")

Мне не понятно, а для чего нужно извлекать адрес ячейки? Возможно это есть основное условие? Формула сделана без извлечения адреса. Возможно это не правильно.

Изменено: gling - 17.11.2023 23:11:53
 
 
 
#5
18.11.2023 19:16:07
Цитата
написал:
Мне не понятно, а для чего нужно извлекать адрес ячейки? Возможно это есть основное условие? Формула сделана без извлечения адреса. Возможно это не правильно
Добрый день, спасибо большое за ваш вариант! Задача - найти последние данные за каждый месяц по каждой категории из столбца С. В связи с необходимость. искать последнюю запись с данными за месяц я искала последнюю запись, затем последнюю непустую запись с данными из столбца D. Но эта функция не может искать по критерию из столбца С, поэтому ваш вариант интереснее, единственное, я добавила больше данных, чтобы проверить как работает функция, но кажется что-то идет не так.


Спасибо.
 
 
 
#6
18.11.2023 19:29:21
Цитата
написал:
но кажется что-то идет не так.
Вы правы. В вашем примере был только один 2019 год, по этому в формуле не проверялся этот параметр. А в новом файле есть разные годы, а месяцы в них одинаковые, по этому формула берет данные месяца, последнего по списку года.
В формулу добавил проверку года.
Код
=ЕСЛИОШИБКА(ПРОСМОТР(99999;ЕСЛИ((МЕСЯЦ($A$1:$A$9000)=МЕСЯЦ(F2))*(ГОД($A$1:$A$9000)=ГОД(F2))*($C$1:$C$9000=$Q$1)*$D$1:$D$9000;$D$1:$D$9000;""));"Нет данных")
Изменено: gling - 18.11.2023 19:38:45
 
 
 
#7
18.11.2023 20:14:51
Спасибо, единственное, почему-то в первой ячейке в март 2019 по всем проверенным скважинам ошибочные данные, в чем может быть причина?
 
 
 
#8
18.11.2023 21:31:12
Цитата
написал:
в чем может быть причина?
Копировал формулу для ответа и не ввел её как формулу массива. Введите её в ячейке Q2 с помощью трех клавиш Shift+Ctrl+Enter, как формулу массива.
 
 
 
#9
19.11.2023 09:52:36
Для разнобразия
=ЕСЛИОШИБКА(-ПРОСМОТР(;-1/(C$2:C$11=K$1)/((ТЕКСТ(A$2:A$11;"М.ГГ")=ТЕКСТ(F2;"М.ГГ"))/D$2:D$11));"нет замеров")
 
 
 
#10
19.11.2023 18:06:59
Цитата
написал:
Копировал формулу для ответа и не ввел её как формулу массива. Введите её в ячейке Q2 с помощью трех клавиш Shift+Ctrl+Enter, как формулу массива.
Добрый день, спасибо большое! протянула формулу снизу вверх на первую ячейку и все теперь работает верно.
 
 
 
Страницы: 1
Наверх