Поиск  Пользователи  Правила  Войти
Форумы "Планета Excel" » Вопросы по Microsoft Excel
Страницы: 1
RSS
Посчитать общее количество заполненных ячеек в строке, напротив списка имен, Возможно, VLOOKUP + HLOOKUP
 
#1
17.11.2023 16:55:06
Добрый день, коллеги. Весь день тереблю алису, но никак не поймем друг друга, как составить следующую формулу:

Есть таблица, в столбце A находится список имен. По горизонтали расположены даты текущего месяца.

Таблица заполнена таким образом, что напротив каждой фамилии за определенную дату стоит любой текст. В другой таблице с этим же списком имен в столбце А, в ячейках B1 и C1 я передаю две даты, которые будут аргументами искомой формулы, которая должна посчитать количество непустых ячеек, напротив данной фамилии а указанном диапазоне дат, которые будут указаны в ячейках B1, C1
 
 
 
#2
17.11.2023 17:13:28
День добрый Allkraft,  вот эта формула:
=СЧЁТЕСЛИМН(Sheet1!$B2:$AE2;"<>";Sheet1!$B$1:$AE$1;">="&B$2;Sheet1!$B$1:$AE$1;"<="&C$2)
у вас заработает, но текст похожий на даты надо сделать именно датами
 
 
 
#3
17.11.2023 17:19:06
Вот такая конструкция получилась
=СЧЁТ(ДВССЫЛ(АДРЕС(ПОИСКПОЗ(A3;Sheet1!$A$2:$A$4;0)+1;ПОИСКПОЗ(B2;Sheet1!$B$1:$AE$1;0)+1;4;1;"Sheet1")&":"&АДРЕС(ПОИСКПОЗ(A3;Sheet1!$A$2:$A$4;0)+1;ПОИСКПОЗ(C2;Sheet1!$B$1:$AE$1;0)+1;4;1)))
Согласие есть продукт при полном непротивлении сторон.

Контакты, благодарности
 
 
 
#4
17.11.2023 17:24:11
Доброго времени, для коллекции))
=СУММПРОИЗВ((Sheet1!$A$2:$A$20=Sheet2!$A3)*(Sheet1!$B$1:$AE$1<=C$2)*(Sheet1!$B$1:$AE$1>=B$2)*(Sheet1!$B$2:$AE$20<>""))
Изменено: Behruz A.N. - 17.11.2023 17:25:37
Вредить легко, помогать трудно.
 
 
 
#5
17.11.2023 17:26:01
Еще вариант массивная
Код
=СЧЁТ(1/ДЛСТР(ИНДЕКС(Sheet1!$B2:$AE2;ПОИСКПОЗ(B$2;Sheet1!$B$1:$AE$1)):ИНДЕКС(Sheet1!$B2:$AE2;ПОИСКПОЗ(C$2;Sheet1!$B$1:$AE$1))))
Алексей М.
 
 
 
#6
17.11.2023 17:31:42
Цитата
написал:
День добрый  Allkraft ,  вот эта формула:=СЧЁТЕСЛИМН(Sheet1!$B2:$AE2;"<>";Sheet1!$B$1:$AE$1;">="&B$2;Sheet1!$B$1:$AE$1;"<="&C$2)у вас заработает, но текст похожий на даты надо сделать именно датами
А если я поменяю даты в ячейках, поиск произйодет?

По поводу даты, я выделяю и вызываю Format----> Выбираю ти Date-----> пытаюсь менять формат представления, ничего не происходит. Также, впервые такая фигня со вставкой, пытаюсь, например, вставить вашу формулой, она вставляется поверх ячейки, а не как формула. Раньше такого не встречал.  
 
 
 
#7
17.11.2023 17:54:41
Вечная тема...
1. Выделяете ячейки с псевдодатами
2. Ctrl+H (или на ленте найдите комаду Заменить)
3. В поле Найти  /    а в поле Заменить - точка
4. Заменить все
5. Проверьте: раширьте столбец - текст "жмется" влево, а даты как и числа - вправо (при неуказанном выравнивании)
Цитата
вставляется поверх ячейки, а не как формула
измените на формат Общий
Изменено: Павел \Ʌ/ - 17.11.2023 17:56:17
 
 
 
#8
17.11.2023 18:19:21
Цитата
написал:
Вечная тема...1. Выделяете ячейки с псевдодатами2. Ctrl+H (или на ленте найдите комаду Заменить)3. В поле Найти  /    а в поле Заменить - точка4. Заменить все5. Проверьте: раширьте столбец - текст "жмется" влево, а даты как и числа - вправо (при неуказанном выравнивании)Цитатавставляется поверх ячейки, а не как формулаизмените на формат Общий
Да, представляю, что тема такая... теперь я запомнил лайфхак). Спасибо!
 
 
 
#9
17.11.2023 19:23:19
Цитата
написал:
Вечная тема...1. Выделяете ячейки с псевдодатами2. Ctrl+H (или на ленте найдите комаду Заменить)3. В поле Найти  /    а в поле Заменить - точка4. Заменить все5. Проверьте: раширьте столбец - текст "жмется" влево, а даты как и числа - вправо (при неуказанном выравнивании)
Это какой то замкнутый круг. Просто копирую ячейку с датой в другой лист и опять двадцать пять, не дата. У меня английская версия эксель. Как эту беду победить раз и навсегда.
 
 
 
#10
17.11.2023 19:41:26
=SUMPRODUCT((Sheet1!$B$1:$AF$1-B$2>=0)*(Sheet1!$B$1:$AF$1-C$2<=0)*(INDEX(Sheet1!$B:$AF;MATCH(A3;Sheet1!$A:$A;);)<>""))
По вопросам из тем форума, личку не читаю.
 
 
 
#11
20.11.2023 13:47:59
А как подсчитать сумму по такому диапазон. Вообще, среднее значение. Но знаменатель можно взять из написанных формул. Пытаюсь понять логику составления формулы. Для знаменателя я использовал : =SUMPRODUCT((Sheet1!$A$2:$A$20=Sheet2!$A3)*(Sheet1!$B$1:$AE$1<=C$2)*(Sheet1!$B$1:$AE$1>=B$2)*(Sheet1!$B$2:$AE$20<>""))


UPD

Сам решил)

=SUMPRODUCT((J3:J35=A3)*(K2:AN2>=B2)*(K2:AN2<=C2)*K3:AN3)
Изменено: Allkraft - 20.11.2023 14:52:58
 
 
 
Страницы: 1
Наверх