Function ulam_spiral(n As Long) As Variant()
    Dim not_primes() As Boolean
    Dim matrix() As Variant
    Dim i As Long, j As Long, x As Long, y As Long
    Dim dx As Long, dy As Long, dx_prev As Long
    
    ReDim not_primes(n * n) As Boolean
    not_primes(0) = True
    not_primes(1) = True
    
    i = 2
    While i <= n
        If Not not_primes(i) Then
            For j = i * i To n * n Step i
                not_primes(j) = True
            Next j
        End If
        i = i + 1
    Wend
    
    ReDim matrix(1 To n, 1 To n) As Variant
    x = n
    y = n
    dx = -1
    dy = 0
    matrix(y, x) = -1
    For i = n * n - 1 To 1 Step -1
        If x + dx < 1 Or x + dx > n Or y + dy < 1 Or y + dy > n Then
            dx_prev = dx
            dx = -dy
            dy = dx_prev
        ElseIf matrix(y + dy, x + dx) <> 0 Then
            dx_prev = dx
            dx = -dy
            dy = dx_prev
        End If
        x = x + dx
        y = y + dy
        If not_primes(i) Then
            matrix(y, x) = -1
        Else
            matrix(y, x) = i
        End If
    Next i
    
    For y = 1 To n
        For x = 1 To n
            If matrix(y, x) = -1 Then
                matrix(y, x) = Empty
            End If
        Next x
    Next y
    
    ulam_spiral = matrix
End Function

Sub main()
    Dim n As Long
    n = Val(InputBox("Введите нечетное положительное N (от 1 до 999"))
    If n < 1 Or n Mod 2 = 0 Or n > 999 Then
        MsgBox ("Неверное значение N")
        Exit Sub
    End If
    
    Cells.Clear
    Cells(1, 1).Resize(n, n) = ulam_spiral(n)
    Cells(1, 1).Resize(n, n).EntireColumn.AutoFit
    
End Sub

Sub DeleteActiveSheet()
    Application.DisplayAlerts = False
    ActiveSheet.Delete
    Application.DisplayAlerts = True
End Sub