Public Const FORMAT_YMD As String = "yyyy-mm-dd"
Public Const FORMAT_US As String = "m""/""d""/""yyyy" ' "mm/dd/yyyy"
Public Const FORMAT_CURRENT As String = FORMAT_YMD ' ...or FORMAT_YMD, should something go wrong
'

Public Function AF_Dates_Period(tabRange As Excel.Range, ByVal lCol As Long, ByVal sCrit1 As String, ByVal dDate1 As Date, _
                                      Optional ByVal sCrit2 As String, Optional ByVal dDate2 As Date = 0) As Long
    sCrit1 = sCrit1 & Format(dDate1, FORMAT_CURRENT): sCrit2 = sCrit2 & Format(dDate2, FORMAT_CURRENT)
    If dDate2 = 0 Then
        tabRange.AutoFilter Field:=lCol, Criteria1:=sCrit1, Operator:=xlFilterValues
    Else
        tabRange.AutoFilter Field:=lCol, Criteria1:=sCrit1, Operator:=xlAnd, Criteria2:=sCrit2
    End If
    
    AF_Dates_Period = AFCountVisibleRows(tabRange.Worksheet) - 1
End Function

Public Function AF_Dates_Multiple(tabRange As Excel.Range, ByVal lCol As Long, ByVal dDates As Variant) As Long
' dDates MUST be a date or a 0-based array
Dim a As Variant, arrCount As Long, i As Long
    If Not IsArray(dDates) Then
        If IsDate(dDates) Then
            dDates = Array(dDates)
        Else
            Exit Function ' Null is not an array either
        End If
    End If
    arrCount = (UBound(dDates) + 1) * 2 - 1
    ReDim a(0 To arrCount)
    For i = 0 To arrCount Step 2
        a(i) = 2: a(i + 1) = Format(dDates(i / 2), FORMAT_CURRENT)
    Next
    tabRange.AutoFilter Field:=lCol, Operator:=xlFilterValues, Criteria2:=a
    AF_Dates_Multiple = AFCountVisibleRows(tabRange.Worksheet) - 1
End Function

Public Sub TestFilter()
Dim tRange As Excel.Range, ws As Excel.Worksheet
Dim dDate As Date, dDate2 As Date, dDate3 As Date

    dDate = CDate("23.07.2019"): dDate2 = CDate("25.07.2019"): dDate3 = CDate("27.07.2019")
    Set ws = Worksheets("WTab1"): Set tRange = ws.Range("Table1")
    AFShowAll ws ' clear autofilters
    
    'Usage 1: Date period "starts from"
    Debug.Print AF_Dates_Period(tRange, 1, ">=", dDate): Stop
    'Usage 2: Date period "from - to"
    Debug.Print AF_Dates_Period(tRange, 1, ">", dDate, "<", dDate3): Stop
    'Usage 3: Single date "equals to"
    Debug.Print AF_Dates_Multiple(tRange, 1, dDate2): Stop
    'Usage 3: Multiple dates
    Debug.Print AF_Dates_Multiple(tRange, 1, Array(dDate, dDate2, dDate3)): Stop

End Sub

' ''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
' ''''''''' Service part - AutoFilter shortcut functions
' ''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
'
Public Function AFShowAll(ws As Excel.Worksheet)
    On Error Resume Next ' if all data is shown, an error will be raised
    ws.ShowAllData
    On Error GoTo 0
End Function

Public Function AFCountVisibleRows(ws As Excel.Worksheet) As Long
Dim sourceRange As Excel.Range, xRange As Excel.Range, lCount As Long
    On Error Resume Next
    Set sourceRange = ws.AutoFilter.Range.SpecialCells(xlCellTypeVisible) ' at least the header SHOULD be visible
    On Error GoTo 0
    If sourceRange Is Nothing Then Exit Function
    For Each xRange In sourceRange.Areas
        lCount = lCount + xRange.Rows.Count
    Next
    AFCountVisibleRows = lCount
End Function

Для фильтрации по некоторому множеству периодов,
как если бы они выбирались из выпадающего списка автофильтра,
используйте Operator:=xlFilterValues, а в Criteria2 передайте особо сконструированный массив. 
Первый элемент массива - код периода, второй - последняя дата в этом периоде.

Первое число (Прим. переводчика: в оригинале - "измерение", но это неверно, потому что 
передаваемый массив одномерный, передача двумерного вызывает ошибку) - код периода дат:
      '0-Годы
      '1-Месяцы
      '2-Дни
      '3-Часы
      '4-Минуты
      '5-Секунды

Таким образом, например, для того чтобы отфильтровать 
январь, апрель, июль и октябрь 2015 года, примените следующий фильтр:
    .AutoFilter Field:=iCol, Operator:=xlFilterValues, _
                Criteria2:=Array(1, "1/31/2015", 1, "4/30/2015", 1, "7/31/2015", 1, "10/31/2015")

Public Sub FilterTest_ByTableFormat()
Dim tRange As Excel.Range, tRange2 As Excel.Range, dDate As Date
Dim sFormat As String

    dDate = CDate("24.07.2019")

    Set tRange = Application.Worksheets("Таблица").Range("Таблица")
    Set tRange2 = Application.Worksheets("Таблица (2)").Range("Таблица2")

    AFShowAll tRange.Worksheet
    AFShowAll tRange2.Worksheet
    
    sFormat = tRange.Item(1).Offset(1, 0).NumberFormat
    tRange.AutoFilter 1, Format(dDate, sFormat), xlFilterValues

    sFormat = tRange2.Item(1).Offset(1, 0).NumberFormat
    tRange2.AutoFilter 1, Format(dDate, sFormat), xlFilterValues

End Sub

Public Function AFShowAll(ws As Excel.Worksheet)
    On Error Resume Next ' if all data is shown, an error will be raised
    ws.ShowAllData
    On Error GoTo 0
End Function

.AutoFilter Field:=1, Operator:= xlFilterValues, Criteria2:=Array(2, "2019-07-24", 2, "2019-07-26")

Public Sub FilterTest_CellValue()
Dim tRange As Excel.Range, tRange2 As Excel.Range, dDate As Date, dDate1 As Date

    dDate = CDate("24.07.2019"): dDate1 = CDate("27.07.2019")

    Set tRange = Application.Worksheets("Таблица").Range("Таблица")
    Set tRange2 = Application.Worksheets("Таблица (2)").Range("Таблица2")

    SetDateFilter_ByCellValue tRange, 1, "=", dDate
    SetDateFilter_ByCellValue tRange2, 1, "=", dDate
    Stop

    SetDateFilter_ByCellValue tRange, 1, ">=", dDate
    SetDateFilter_ByCellValue tRange2, 1, ">=", dDate
    Stop

End Sub

Public Function SetDateFilter_ByCellValue(tabRange As Excel.Range, ByVal lCol As Long, ByVal sCriteria As String, ByVal dDate As Date)
Dim colRange As Excel.Range
Dim xRange As Excel.Range, v As Variant

    Set colRange = tabRange.Columns(lCol)
    Set xRange = colRange.Find(dDate)

    If (xRange Is Nothing) Then Exit Function

    AFShowAll tabRange.Worksheet

    tabRange.AutoFilter lCol, sCriteria & xRange.Value

End Function

Public Sub FilterNumbers()
Dim v As Variant, c As Currency, sFormat As String
Dim xRange As Excel.Range, ws As Excel.Worksheet

    v = InputBox("Число нужно", , 3)
    If v = "" Or (Not IsNumeric(v)) Then Exit Sub
    c = CCur(v)
    
    Set ws = ThisWorkbook.Worksheets(1)
    Set xRange = ws.Range("TheTable")
    
    AFShowAll ws

            sFormat = xRange(1).Offset(1, 0).NumberFormat

    xRange.AutoFilter 1, "=" & Format(c, sFormat)

    MsgBox "У меня получилось?", vbQuestion + vbYesNo
    
End Sub

Public Sub FilterNumbersRange()
Dim v As Variant, c As Currency, c1 As Currency, sFormat As String
Dim xRange As Excel.Range, ws As Excel.Worksheet

    v = InputBox("Число нужно, для начала", , 2)
    If v = "" Or (Not IsNumeric(v)) Then Exit Sub
    c = CCur(v)
    
    v = InputBox("А теперь еще одно число, в конец", , 4)
    If v = "" Or (Not IsNumeric(v)) Then Exit Sub
    c1 = CCur(v)
    
    Set ws = ThisWorkbook.Worksheets(1)
    Set xRange = ws.Range("TheTable")
    
    AFShowAll ws
    
            sFormat = xRange(1).Offset(1, 0).NumberFormat

    xRange.AutoFilter 1, ">=" & Format(c, sFormat), xlAnd, "<=" & c1

    MsgBox "А так получилось?", vbQuestion + vbYesNo
    
End Sub

Public Function AFShowAll(ws As Excel.Worksheet)
    On Error Resume Next ' if all data is shown, an error will be raised
    ws.ShowAllData
    On Error GoTo 0
End Function

Public Sub FilterTestYMD()
Dim tRange As Excel.Range, tRange2 As Excel.Range, dDate As Date, dDate1 As Date

    dDate = CDate("24.07.2019"): dDate1 = CDate("27.07.2019")

    Set tRange = Application.Worksheets("Таблица").Range("Таблица")
    Set tRange2 = Application.Worksheets("Таблица (2)").Range("Таблица2")
    
    MsgBox "Testng YMD format." & vbCrLf & "Filtering =""" & dDate & """.", vbInformation
    SetDateFilterYMD tRange, 1, "=", dDate
    SetDateFilterYMD tRange2, 1, "=", dDate
    Stop

    MsgBox "Testng YMD format." & vbCrLf & "Filtering >=""" & dDate & """.", vbInformation
    SetDateFilterYMD tRange, 1, ">=", dDate
    SetDateFilterYMD tRange2, 1, ">=", dDate
    Stop

    MsgBox "Testng YMD format." & vbCrLf & "Filtering a range between """ & dDate & """ and """ & dDate1 & """.", vbInformation
    SetDateFilterYMD tRange, 1, "between", Array(dDate, dDate1)
    SetDateFilterYMD tRange2, 1, "between", Array(dDate, dDate1)
    Stop

    MsgBox "Testng YMD format." & vbCrLf & "Filtering by an array of """ & dDate & """ and """ & dDate1 & """.", vbInformation
    SetDateFilterYMD tRange, 1, "=", Array(dDate, dDate1)
    Stop

End Sub

Public Function SetDateFilterYMD(tabRange As Excel.Range, ByVal lCol As Long, ByVal sCriteria As String, _
                              ParamArray dDates() As Variant)
' works via CLng() conversion
Const YMDFormat As String = "yyyy-mm-dd"
Dim a As Variant, i As Long, a1 As Variant
    If IsMissing(dDates) Then Exit Function
    If IsArray(dDates(0)) Then
        a = dDates(0)
    Else
        a = dDates
    End If
    AFShowAll tabRange.Worksheet
    If UBound(a) - LBound(a) = 0 Then ' a single value
        tabRange.AutoFilter lCol, sCriteria & Format(a(LBound(a)), YMDFormat)
    Else
        ' "array" works only for "=" and "between" criteria ("<>" is not included so far)
        If sCriteria = "between" Then
            ' first two values only are used
            For i = LBound(a) To UBound(a)

                a(i) = CStr(Format(a(i), YMDFormat)) ' cstr because the function returns Variant...
                                                     'God knows if cstr does any good but no harm anyway
            Next
            tabRange.AutoFilter lCol, ">=" & a(LBound(a)), xlAnd, "<=" & a(LBound(a) + 1)
        Else
            ReDim a1(LBound(a) To (UBound(a) - LBound(a) + 1) * 2 - 1)
            For i = LBound(a) To UBound(a)
                a1(i * 2) = 2: a1(i * 2 + 1) = Format(a(i), YMDFormat)
            Next
            tabRange.AutoFilter Field:=lCol, Operator:=xlFilterValues, Criteria2:=a1
        End If
    End If
End Function

Public Function DateToUS(ByVal dDate As Date) As String
    DateToUS = Format(dDate, "m""/""d""/""yyyy") ' "mm/dd/yyyy"
End Function

Public Function AFShowAll(ws As Excel.Worksheet)
    On Error Resume Next ' if all data is shown, an error will be raised
    ws.ShowAllData
    On Error GoTo 0
End Function

Public Sub FilterEqualOrMore()
Dim tRange As Excel.Range, tRange2 As Excel.Range, dDate As Date

    dDate = CDate("24.07.2019")

    Set tRange = Application.Worksheets("Таблица").Range("Таблица")
    Set tRange2 = Application.Worksheets("Таблица (2)").Range("Таблица2")

    ' via DateToUs
    SetDateFilter tRange, 1, dDate, ">="
    SetDateFilter tRange2, 1, dDate, ">="
    Stop

    ' via "Short Date" format
    SetDateFilter2 tRange, 1, dDate, ">="
    SetDateFilter2 tRange2, 1, dDate, ">="
    Stop

    ' via CStr conversion
    SetDateFilter3 tRange, 1, dDate, ">="
    SetDateFilter3 tRange2, 1, dDate, ">="
    Stop

    ' via CLng conversion
    SetDateFilterCLNG tRange, 1, dDate, ">="
    SetDateFilterCLNG tRange2, 1, dDate, ">="
    Stop

     ' via CDbl conversion
    SetDateFilterCDBL tRange, 1, dDate, ">="
    SetDateFilterCDBL tRange2, 1, dDate, ">="

End Sub

Public Sub FilterEqual()
Dim tRange As Excel.Range, tRange2 As Excel.Range, dDate As Date

    dDate = CDate("24.07.2019")

    Set tRange = Application.Worksheets("Таблица").Range("Таблица")
    Set tRange2 = Application.Worksheets("Таблица (2)").Range("Таблица2")

    ' via DateToUs
    SetDateFilter tRange, 1, dDate, "="
    SetDateFilter tRange2, 1, dDate, "="
    Stop
    
    ' via "Short Date" format
    SetDateFilter2 tRange, 1, dDate, "="
    SetDateFilter2 tRange2, 1, dDate, "="
    Stop
    
    ' via CStr conversion
    SetDateFilter3 tRange, 1, dDate, "="
    SetDateFilter3 tRange2, 1, dDate, "="
    Stop

    ' via CLng conversion
    SetDateFilterCLNG tRange, 1, dDate, "="
    SetDateFilterCLNG tRange2, 1, dDate, "="
    Stop
    
     ' via CDbl conversion
    SetDateFilterCDBL tRange, 1, dDate, "="
    SetDateFilterCDBL tRange2, 1, dDate, "="
    Stop
   
   'via the CraftyGimmick
    SetDateFilterEqual_HitroTryuk tRange, 1, dDate
    SetDateFilterEqual_HitroTryuk tRange2, 1, dDate
    
    
End Sub

Public Function SetDateFilter(tabRange As Excel.Range, ByVal lCol As Long, ByVal dDate As Date, _
                              Optional ByVal sCriteria As String = "=")
' works via DateToUS conversion
    AFShowAll tabRange.Worksheet
    tabRange.AutoFilter lCol, sCriteria & DateToUS(dDate)
End Function

Public Function SetDateFilter2(tabRange As Excel.Range, ByVal lCol As Long, ByVal dDate As Date, _
                              Optional ByVal sCriteria As String = "=")
' via Format("Short Date") conversion
    AFShowAll tabRange.Worksheet
    tabRange.AutoFilter lCol, sCriteria & Format(dDate, "Short Date")
End Function

Public Function SetDateFilter3(tabRange As Excel.Range, ByVal lCol As Long, ByVal dDate As Date, _
                              Optional ByVal sCriteria As String = "=")
' works via Cstr() conversion
    AFShowAll tabRange.Worksheet
    tabRange.AutoFilter lCol, sCriteria & CStr(dDate)
End Function

Public Function SetDateFilterCLNG(tabRange As Excel.Range, ByVal lCol As Long, ByVal dDate As Date, _
                              Optional ByVal sCriteria As String = "=")
' works via CLng() conversion
    AFShowAll tabRange.Worksheet
    tabRange.AutoFilter lCol, sCriteria & CLng(dDate)
End Function

Public Function SetDateFilterCDBL(tabRange As Excel.Range, ByVal lCol As Long, ByVal dDate As Date, _
                              Optional ByVal sCriteria As String = "=")
' works via CLng() conversion
    AFShowAll tabRange.Worksheet
    tabRange.AutoFilter lCol, sCriteria & CDbl(dDate)
End Function


Public Function SetDateFilterEqual_HitroTryuk(tabRange As Excel.Range, ByVal lCol As Long, ByVal dDate As Date)
' via the CraftyGimmick
    AFShowAll tabRange.Worksheet
    tabRange.AutoFilter lCol, ">=" & DateToUS(dDate), xlAnd, "<=" & DateToUS(dDate)
End Function

"Операция", "Настройка на операцию"
"№ пп", "9"
"Код заказа", "2019-03-01 Fuji"
"Приоритет", "1"

Public Function DebugPivot()
Dim xRange As Excel.Range, xpCell As Excel.PivotCell, i As Long
Dim cll As Collection, a As Variant

    On Error Resume Next
    Set xRange = Selection: Set xRange = xRange.Item(1)
    Set xpCell = xRange.PivotCell
    On Error GoTo 0

   
    If xpCell Is Nothing Then Exit Function
    
    Set cll = New Collection

    For i = 1 To xpCell.RowItems.Count
        cll.Add Array(xpCell.RowItems(i).Parent.Name, xpCell.RowItems(i).Value)
    Next
    For i = 1 To xpCell.ColumnItems.Count
        cll.Add Array(xpCell.ColumnItems(i).Parent.Name, xpCell.ColumnItems(i).Value)
    Next

    For Each a In cll
        Debug.Print a(0), a(1)
    Next
   
End Function

For Each xRowDataItem in ????????
 Debug.Print xRowDataItem.Name, xRowDataItem.Value
Next

Операция     Фрезеровка. SPRINTER (I проход)
№ пп     4
Код заказа     2019-03-01 Fuji
Приоритет    1