Поиск  Пользователи  Правила  Войти
Форумы "Планета Excel" » Пользователи » memo
Выбрать дату в календаре…Выбрать дату в календаре

Страницы: 1 2 3 4 5 6 7 8 9 10 11 ... 55 След.
Распределение данных по разным столбцам
 
#
19.11.2025 21:55:07
Еще вариант, одной формулой:
=IFERROR(INDEX(($E$1:$E$46;$F$1:$F$46);AGGREGATE(15;6;ROW($E$1:$E$46)/($D$1:$D$46=$D5);INT(COLUMN(B5)/2));;MOD(COLUMN();2)+1);"")
 
Перейти    
Как добавить в текст символы (точки), Необходимо в текст добавить в разные места точки
 
#
28.10.2025 19:26:42
Цитата
Dimkinjune написал:
как сдесь сделать:8242860002429        8.2428.6.000.242.9
Вариант.
=TEXT(A1;"0\.0000\.0\.000\.000\.0")
 
Перейти    
Найти в таблице минимальное значение из максимальных значений в строках.
 
#
15.10.2025 00:48:36
Вариант.
=MIN(SUBTOTAL(4;OFFSET(B2;ROW(1:15);;;11)))
 
Перейти    
ПРОСМОТРX не проливается в двух направлениях
 
#
09.10.2025 12:44:40
Пару раз сталкивался с подобным и покопавшись на форумах обнаружил, что в случае с XLOOKUP это известно как Array of Arrays problem. Есть парочка решений, через комбинацию LAMBDA, DROP, REDUCE и XLOOKUP. Самое простое это вообще не использовать XLOOKUP а обойтись комбинацией CHOOSEROWS + XMATCH. Например так: =CHOOSEROWS(C3:E27;XMATCH(H17:H27;B3:B27;0))
 
Перейти    
формула расчета трудозатрат, прошу помочь с выполнением задания.
 
#
05.08.2025 14:53:35
Цитата
girvad написал:
чтобы по двум датам определяла диапозон, в котором надо считатьсумму и просто складывала значения
А сейчас не складывает?
 
Перейти    
Подсчет количества рабочих дней
 
#
05.08.2025 01:30:15
Еще вариант кол-ва пятниц в текущем месяце (дата в А1):
=4+(DAY(A1-DAY(A1)+35)<WEEKDAY(A1-DAY(A1)-5))
(1-Понедельник---->7-Воскресенье)
 
Перейти    
формула расчета трудозатрат, прошу помочь с выполнением задания.
 
#
04.08.2025 23:07:08
Обновил пост. Добавил УФ.
 
Перейти    
формула расчета трудозатрат, прошу помочь с выполнением задания.
 
#
04.08.2025 19:04:00
Как-то так.
Изменено: memo - 04.08.2025 23:06:28 (Добавил УФ)
 
Перейти    
пропорциональное уменьшение значений в группе ячеек на опреденноё число
 
#
22.07.2025 23:38:37
Эмм.. может так?
=SUM(A3:A94)-C3
 
Перейти    
Динамисеская подмена данных по номеру из массива другой таблицы
 
#
22.07.2025 23:34:25
Еще вариант для А2:
Код
=FILTERXML("<t><s>"&SUBSTITUTE(SUBSTITUTE(C2;":";",");",";"</s><s>")&"</s></t>";"//s[preceding::*='"&A$1&"']")
 
Перейти    
Условие для СУММПРОИЗВ в работе с текстовыми значениями
 
#
18.07.2025 22:17:07
Можно слегка подправить:
=SUMPRODUCT(TEXT(0&MID(D4:D18;1;SEARCH("/";D4:D18&"/")-1);"00;;0;\0")*ISTEXT(D4:D18))
 
Перейти    
Как создать автоматическое построение списка, без пустых строк
 
#
08.07.2025 12:34:01
Цитата
AlienSx написал:
неа, TRIMRANGE "рубит хвосты" и не трогает то, что внутри.
Excel 365 (Онлайн) так не считает:)
 
Перейти    
Как создать автоматическое построение списка, без пустых строк
 
#
08.07.2025 11:24:47
Если версия позволяет то можно и так:
=TRIMRANGE(UNIQUE(B:B))
 
Перейти    
поиск даты в множестве дат, расположенных в одной ячейке, поиск даты
 
#
07.07.2025 23:09:01
Сколько здесь писали о файле, примере - не перечесть.
Вариант (формула массива):
=MAX(IFERROR(--MID(SUBSTITUTE(A1;".";"/");(ROW($1:$10)-1)*10+1;10);0))
Если у вас используется точка в качестве разделителя, то можете убрать этот блок:
=SUBSTITUTE(A1;".";"/") и оставить А1
 
Перейти    
Автоматизация расчета доли продаж за каждый квартал
 
#
01.07.2025 22:03:11
Еще вариант:
=SUM(INDEX($B3:$M3;(3*COLUMNS($B$3:B3)-3)+1):INDEX($B3:$M3;(3*COLUMNS($B$3:B3)-3)+3))
 
Перейти    
Суммирование ячеек с заменой переменной на число
 
#
28.06.2025 18:59:30
Ну и напоследок (можно не вводить как формулу массива и порядок тоже наводить не обязательно):
=СУММ(ИНДЕКС(--ТЕКСТ(ПОДСТАВИТЬ(B2:E2;"к";);"0;;0;\0");0);8*СЧЁТЕСЛИ(B2:E2;"*к"))
Изменено: memo - 28.06.2025 19:01:40
 
Перейти    
Суммирование ячеек с заменой переменной на число
 
#
28.06.2025 16:59:09
Цитата
ZhSAleksnandrov написал:
Еще одна сиутация не обыграна, когда просто "К" без чисел  
Тогда "лобовое" решение:
=IF(ISNUMBER(B2);B2;IFERROR(--LEFT(B2);0))+IF(ISNUMBER(E2);E2;IFERROR(--LEFT(E2);0))+8*COUNTIF(B2:G2;"*к")
 
Перейти    
Суммирование ячеек с заменой переменной на число
 
#
28.06.2025 15:56:00
ZhSAleksnandrov, Здравствуйте.
Так?
=B2+LEFT(E2)+8*COUNTIF(B2:G2;"*к")
 
Перейти    
Фильтрация данных, Фильтрация данных
 
#
27.06.2025 11:52:58
Kuzya_228_227,
Урок рабочий, просто вы невнимательны к деталям. По формуле в ячейке F3:
1. Условие в ячейке F1 ссылается на диапазон в столбце А, в котором числа. Нет там арбузов, дынь и прочих нитратосодержащих фруктов (ягод, с ботанической точки зрения :)  )
2. Более того нарушена размерность. Везде граница диапазона заканчивается на 2252, а в столбце А на 2000. Непорядок.
3. Для функции СТРОКА диапазон указан кириллицей. Естественно, функция с ней работать не будет.
4. Этот пункт: СТРОКА()-5. В уроке написано:
Цитата
...для компенсации сдвига результирующего диапазона относительно исходного вычитается число пять во фрагменте СТРОКА()-5
Но, поскольку формула у вас третьей строке, то для получения единицы нужно вычесть не пять а два.
5. Ну и когда вы это исправите введите формулу через Ctrl + Shift + Enter (там, кстати тоже об этом написано).
 
Перейти    
Извлечь строку текста из ячейки
 
#
26.06.2025 21:52:20
=TRIM(RIGHT(SUBSTITUTE(A1;" ";REPT(" ";15));15))
 
Перейти    
Подсчет итога по критериям других ячеек
 
#
14.06.2025 23:47:17
Как вариант:
=SUMPRODUCT(COUNTIF($E4:$AI4;{8\12\24})*$B4:$D4)
 
Перейти    
Поиск нескольких значений с выводом определенной ячейки, Поиск нескольких значений с выводом определенной ячейки
 
#
05.06.2025 19:26:14
Формулами, правда довольно таки громоздкими (массивными естественно).
Фрукты:
=IFERROR(INDEX($B$3:$B$8;MATCH(0;INDEX(--(COUNTIF($L$2:L2;$B$3:$B$8)=MMULT(--(ISNUMBER($C$3:$G$8));{1;1;1;1;1}));0);0));"")

Недели:
=IFERROR(INDEX($C$2:$G$2;SMALL(IF((IF(MATCH($B$3:$B$8;$B$3:$B$8;0)=(ROW($B$3:$B$8)-ROW($B$3)+1);$B$3:$B$8)=$L3)*($C$3:$G$8<>"");(COLUMN($C$3:$G$8)-COLUMN(C$3)+1));COUNTIF(L$3:L3;L3)));"")
 
Перейти    
формула среднего значения только заполненных ячеек, не учитывая нули в заполненных ячейках
 
#
24.05.2025 10:52:44
=SUM(D3:O3)/COUNTIF(D3:O3;">0")
=AVERAGEIF(D3:O3;">0";D3:O3)
Массивно:
=AVERAGE(IF(D3:O3;D3:O3))
Изменено: memo - 24.05.2025 10:55:45
 
Перейти    
Уникальное значение из столбца перенести вместе со значениями в соответствующий столбец
 
#
22.05.2025 20:19:17
Можно и без СМЕЩ. Простые варианты в файле.
 
Перейти    
Вывести минимальные и максимальные значения из промежутков последовательных чисел
 
#
17.05.2025 16:55:05
BodkhiSatva,
Все отлично. Только дома у меня по-прежнему Excel 2013-2016, где нет функции TEXTJOIN().
Сейчас пытаюсь разобраться, почему не работает последний вариант от Павел \Ʌ/,

UPDATE: Кажется разобрался. Дело в том, что ИНДЕКС в Excel 2013-2016 (не знаю, как в 2019) по-умолчанию не поддерживает массив строк (в качестве второго аргумента). Но, тем не менее есть некий трюк, который позволяет это сделать.

Вот такой вариант работает:
Код
=IFERROR(INDEX(B$2:B$22;AGGREGATE(15;6;ROW(B$2:B$22)/(B$2:B$22-INDEX(B$2:B$22;N(INDEX(ROW(B$2:B$22)-ROW(Q$2);)))<>1);ROW(Q1))-ROW(Q$2)+1)&IF(IFERROR(SUM(AGGREGATE(15;6;ROW(B$2:B$22)/(B$2:B$22-INDEX(B$2:B$22;N(INDEX(ROW(B$2:B$22)-ROW(Q$2);)))<>1);ROW(Q1:Q2))*{-1;1})-1;1);"_"&INDEX(B$2:B$22;AGGREGATE(15;6;ROW(B$2:B$22)/(IFERROR(INDEX(B$2:B$22;N(INDEX(ROW(B$2:B$22)-ROW(Q$2)+2;)));B$2:B$22)-B$2:B$22<>1);ROW(Q1))-ROW(Q$2)+1);"");"")


или так:
Код
=IFERROR(INDEX(B$2:B$22;SMALL(IF((B$2:B$22-INDEX(B$2:B$22;N(INDEX(ROW(B$2:B$22)-ROW(R$2);)))<>1);ROW(B$2:B$22));ROW(R1))-ROW(R$2)+1)&IF(IFERROR(SUM(SMALL(IF((B$2:B$22-INDEX(B$2:B$22;N(INDEX(ROW(B$2:B$22)-ROW(R$2);)))<>1);ROW(B$2:B$22));ROW(R1:R2))*{-1;1})-1;1);"_"&INDEX(B$2:B$22;SMALL(IF((IFERROR(INDEX(B$2:B$22;N(INDEX(ROW(B$2:B$22)-ROW(R$2)+2;)));B$2:B$22)-B$2:B$22<>1);ROW(B$2:B$22));ROW(R1))-ROW(R$2)+1);"");"")


(добавлен блок N(INDEX(ROW(B$2:B$22)-ROW(R$2))

Еще раз спасибо вам за этот вариант!
Изменено: memo - 17.05.2025 22:38:18
 
Перейти    
Вывести минимальные и максимальные значения из промежутков последовательных чисел
 
#
17.05.2025 14:15:00
Павел \Ʌ/, Странно, но почему-то на 2013-ом офисе не взлетело.
Скрин
 
Перейти    
Вывести минимальные и максимальные значения из промежутков последовательных чисел
 
#
16.05.2025 18:46:35
Павел \Ʌ/, Metanor,
Спасибо за варианты!  

Павел, понравился ваш вариант с отрицательными числами для старых версий.

БМВ, Благодарствую!
Изменено: memo - 16.05.2025 18:51:44
 
Перейти    
Вывести минимальные и максимальные значения из промежутков последовательных чисел
 
#
16.05.2025 12:58:31
Всем доброго времени суток.
Собственно сабж. В столбце А имеется список из последовательных чисел: 120,121,122 далее следует разрыв и идет число 124, означающее нарушение последовательности и завершение промежутка. С него же и начинается новый 124,125,126 и т.д. пока последовательность снова не нарушится.
В каждом промежутке надо найти начало и конец и прописать через тире. Например для первого это будет 120-122.
В приложенном файле два моих варианта.
Вопрос: можно ли сделать вариант покороче?
 
Перейти    
Вычислить формулу из цифр и букв, Преобразовать цифры и буквы в формулу и вычислить результат
 
#
09.05.2025 22:29:13
Формула массива. Хотя, думаю, вполне можно сообразить покороче и без массива.
=PRODUCT(IFERROR(--TRIM(MID(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(A1;"д";);"х";REPT(" ";15));".";MID(1/2;2;1));{1;15;30};15));0>1))
Перевод формулы на русский: ТЫЦ
Изменено: memo - 09.05.2025 22:31:23
 
Перейти    
Как для таблицы сделать сортировку из нескольких условий ?
 
#
09.05.2025 22:26:50
Не знаю, правильно или нет.
Update: теперь вроде правильно
=IFERROR(INDEX(P:P;ROUND(MOD(LARGE(IF((($U$2:$U$148>0)*($W$2:$W$148>0)*($Y$2:$Y$148>0)*($AA$2:$AA$148>0))*((MATCH($P$2:$P$148;$P$2:$P$148;)=ROW($P$2:$P$148)-ROW($P$1)));$S$2:$S$148*10000+ROW($P$2:$P$148)/10000);ROW(P1));1)*10000;));"")
Изменено: memo - 10.05.2025 11:57:45 (Невнимательность)
 
Перейти    
Страницы: 1 2 3 4 5 6 7 8 9 10 11 ... 55 След.
Наверх