Выбрать дату в календареВыбрать дату в календаре

Страницы: 1 2 3 4 5 6 7 8 9 10 11 ... 39 След.
Как заполнить нужные ячейки нужными значениями
 
Так?
Код
=ИНДЕКС(ДЕНЬ(A:A);ПОИСКПОЗ(1=1;A1:A$50<>"";)+СТРОКА(A1)-1)
Как заполнить нужные ячейки нужными значениями
 
solnce60, Ни в какое место ничего не нужно вставлять, у меня нет таких методов). Мой вариант на английском нужно всего лишь перевести на русский, на указанном мною ресурсе, потому что Ваш русский Excel, увы, не дружит с английским. Полученную формулу на русском вставляете в ячейку В1 без массивного ввода, то бишь без нажатия CTRL+SHIFT+ENTER и протягиваете вниз.

Вот, сделал перевод:
=ИНДЕКС(A:A;ПОИСКПОЗ(1=1;ИНДЕКС(A1:A$50<>"";);)+СТРОКА(A1)-1)
или второй вариант:
=ИНДЕКС($A$1:$A$50;АГРЕГАТ(15;6;СТРОКА($A$1:$A$50)/(A1:A$50<>"");1)+СТРОКА(A1)-1)
Преобразование таблицы: перенос значений из столбцов в строки"
 
Можно формулами.
Изменено: memo - 01.10.2022 23:29:09
Как заполнить нужные ячейки нужными значениями
 
solnce60, Формула Михаила работает, просто она массивная и ее нужно вводить через CTRL+SHIFT+ENTER. Можно в ПОИСКПОЗ добавить ИНДЕКС и сделать немассивной.
=INDEX(A:A;MATCH(1=1;INDEX(A1:A$50<>"";);)+ROW(A1)-1)
или попробовать такой вариант:
=INDEX($A$1:$A$50;AGGREGATE(15;6;ROW($A$1:$A$50)/(A1:A$50<>"");1)+ROW(A1)-1)
Перевод формул на русский ТУТ.
Изменено: memo - 01.10.2022 21:17:34
ВПР для отображения только видимых (отфильтрованных) строк исходной таблицы, Поиск путей отображения с помощью ВПР в зависимой таблице только строк, видимых (отфильтрованных) в исходной таблице
 
Возможно эта тема вам поможет.
Преобразование множества значений из ячейки в строки с повторением соседних столбцов, Преобразование таблицы
 
БМВ, Ну, по идее, кроме точек с запятой там ничего не должно быть, хотя что там будет на практике один автор знает.
Преобразование множества значений из ячейки в строки с повторением соседних столбцов, Преобразование таблицы
 
БМВ, Не перемудрено, скорее перестрахованно. К примеру если у букв поставить лишние точки с запятой ваша формула посчитает их и будет ненужный сдвиг.
Преобразование множества значений из ячейки в строки с повторением соседних столбцов, Преобразование таблицы
 
Формульный вариант.
Первый столбец.
Код
=IF(ROWS(D$1:D1)>SUM(1+LEN(TRIM(SUBSTITUTE($B$1:$B$2&";";"; ";" ")))-LEN(SUBSTITUTE($B$1:$B$2&";";"; ";"")));"";INDEX(A$1:A$2;MATCH(ROWS(D$1:D1)-1;MMULT(--(ROW(A$1:A$2)>TRANSPOSE(ROW(A$1:A$2)));1+LEN(TRIM(SUBSTITUTE($B$1:$B$2&";";"; ";" ")))-LEN(SUBSTITUTE($B$1:$B$2&";";"; ";""))))))

Второй.
Код
=IFERROR(TRIM(MID(SUBSTITUTE(INDEX($B$1:$B$2;MATCH(ROWS(E$1:E1)-1;MMULT(--(ROW($B$1:$B$2)>TRANSPOSE(ROW($B$1:$B$2)));1+LEN(TRIM(SUBSTITUTE($B$1:$B$2&";";"; ";" ")))-LEN(SUBSTITUTE($B$1:$B$2&";";"; ";"")))));"; ";REPT(" ";99));IFERROR(MOD(SMALL(IF(LEN($B$1:$B$2&0)-LEN(SUBSTITUTE($B$1:$B$2;";";))>=COLUMN($A$1:$Z$1);ROW($B$1:$B$2)*100+COLUMN($A$1:$Z$1));ROWS(E$1:E1));100);"")*99-98;99));"")

Обе массивные.
Выпадающий список из умной таблицы по условию столбца, Понимаю что через ДВссыл, но никак прописать не получается
 
Еще.
Код
=INDEX(АССОРТИМЕНТ[ЦВЕТ];MATCH(Лист1!$C40;АССОРТИМЕНТ[Артикул];0)):INDEX(АССОРТИМЕНТ[ЦВЕТ];MATCH(Лист1!C40;АССОРТИМЕНТ[Артикул];0)-1+COUNTIF(АССОРТИМЕНТ[Артикул];Лист1!$C40))

Имя в менеджере имен - ddlist
Копирование столбца с данными N раз, в каждом новом строки не совпадают друг с другом
 
Вот такой вариант. Для начала на Листе3 с малым кол-вом данных.
Код
=IF(((ROWS(A$1:A1)-1)>=$B$2);"";IFERROR(INDEX($A$2:$A$9999;IF(COLUMNS($C$2:C2)>$B$4;"";MOD((ROW(C1)-1)+(COLUMN(C$1)-3)*$B$2;COUNTA($A$2:$A$9999)-1)+2));""))

В ячейке В2 задаем кол-во строк в столбце, в В4 кол-во столбцов.
Копирование столбца с данными N раз, в каждом новом строки не совпадают друг с другом
 
_Boroda_, Я думаю, ТС нужно как на Листе3. Пока сделал вручную, чтобы ТС подтвердил что это то самое.
Копирование столбца с данными N раз, в каждом новом строки не совпадают друг с другом
 
Т.е. число нужных столбцов все таки надо указывать?
Вообще, предполагаю, что макросом это проще сделать чем формулой, может кто возьмется. А я подумаю над формулой.
Копирование столбца с данными N раз, в каждом новом строки не совпадают друг с другом
 
Дмитрий С, Хорошо, давайте все уточним.
Вы указываете нужное кол-во строк, как в ячейке В2 и по указанному числу при копировании в другой столбец должна происходить отсечка данных. Так?
Затем, вы пишите.
Цитата
Дмитрий С написал:
Нужно указать кол-во столбцов
, хотя в примере у вас такого не было. Вы просто упомянули, что данные должны скопироваться на 74 столбца.
У нас уже есть формула, которая это делает, но когда в столбце А кончаются данные, то она естественно начинает возвращать нули.
Но как это совместить с этим?
Цитата
Дмитрий С написал:
Можно ли сделать чтобы не копировать данные ( в столбце А) по 40-50 раз чтобы их хватило на нужное кол-во столбцов ?  
Т.е. формула должна рассчитать на сколько столбцов хватит данных из столбца А? Потому что из вашего примера на 74 столбца их точно не хватает.
Копирование столбца с данными N раз, в каждом новом строки не совпадают друг с другом
 
Это какая-то шутка?
Вами заполненный лист1

Результат работы формулы из сообщения №5 на листе2
Изменено: memo - 26.09.2022 06:47:20
Копирование столбца с данными N раз, в каждом новом строки не совпадают друг с другом
 
Вы последний файл из сообщения №5 (лист2) смотрели? Все в точности с вашим примером. Или я чего-то не понимаю?
Копирование столбца с данными N раз, в каждом новом строки не совпадают друг с другом
 
Дмитрий С, Я же приложил файл. Вставляете в ячейку С2 и тянете вправо и вниз.
Код
=IF((ROWS(A$1:A1)-1)>=$B$2;"";INDEX($A$2:$A$9999;ROW()+(COLUMN()-3)*$B$2))
Копирование столбца с данными N раз, в каждом новом строки не совпадают друг с другом
 
Так?
Код
=IF((ROWS(A$1:A1)-1)>=$B$2;"";INDEX($A$2:$A$9999;ROWS(A$1:A1)+(COLUMN()-3)*$B$2))
Изменено: memo - 25.09.2022 14:17:49
Соответствующие значения столбцам
 
Цитата
Net99 написал:
но кажется слишком замудрённая формула.
Ну, тут, как говорится, Вашей фантазии да карты в руки. Сделайте лучше.
Соответствующие значения столбцам
 
Как вариант:
Код
=IFERROR(FILTERXML("<k><m>"&SUBSTITUTE(SUBSTITUTE($A2;", ";",");",";"</m><m>")&"</m></k>";"//m[contains(.,'"&TRIM(SUBSTITUTE(SUBSTITUTE(B$1;"«";);"»";))&"')][1]");"")
Подсчет количества столбцов с условием., Подсчет количества столбцов с условием
 
Если правильно понял. Формула массива.
Код
=SUM(N(MMULT(TRANSPOSE(N(ISNUMBER($A$3:$AE$7)));ROW($A$3:$AE$7)^0)>1))
Поиск всех значений (текстовых) в одной ячейке из диапазона с возвратом суммы присвоенных параметров
 
Попробуйте так:
=SUMPRODUCT(SUMIFS(Таблица1[Личные баллы];Таблица1[Фамилия участника];TRIM(MID(SUBSTITUTE(F5;", ";REPT(" ";99));ROW($1:$15)*99-98;99))))
Изменено: memo - 22.09.2022 07:34:23
Заполнить ячейку в зависимости от числа похожего текста в диапазоне строк
 
БМВ, Да, споткнется, в виду отсутствия в меню CHOOSE() третьего фрукта, но и с грушами не расстанется.  8)
Заполнить ячейку в зависимости от числа похожего текста в диапазоне строк
 
Вариант на основе формулы от БМВ,
=IFERROR(CHOOSE(("Дерево"=A2)*COUNTIF(INDEX(A:A;LOOKUP(2;1/($C$1:C2<>"");ROW($C$1:C2))):A2;"Дерево");"Яблоня";"Груша");"")
Изменено: memo - 20.09.2022 22:27:19
результат СУММПРОИЗВ в том же массиве, что и слагаемые.
 
Мм..могу ошибаться, но может ТС хочет что-то вроде этого?
Код
=IFERROR(1/(1/(SUMIFS($G$20:$G$33;$B$20:$B$33;B19;$C$20:$C$33;C19;$D$20:$D$33;D19)*(LEFT(E20;5)="итого")));"")
Выборка из ячейки по критерию
 
Можно так:
Код
=INDEX($A$3:$D$6;AGGREGATE(15;6;(ROW($A$3:$D$6)-ROW($A$3)+1)/(ISNUMBER(SEARCH($G$11;$B$3:$B$6)));ROW(A1));MATCH(H$10;$A$2:$D$2;))

или попроще
Код
=INDEX($A$3:$D$6;MATCH(TRUE;INDEX(ISNUMBER(SEARCH($G$11;$B$3:$B$6)););)+ROW(A1)-1;MATCH(H$10;$A$2:$D$2;))
Последовательная нумерация повторящихся значений столбца, со сбросом номера при появлении нового значения в столбце
 
=COUNTIF($A$1:A1;A1)
Определить категрию по частичному совпадению текста
 
Так?
Код
=LOOKUP(2;1/(ISNUMBER(SEARCH($G$1:$G$5;A1)));$H$1:$H$5)

Кстати, в этой комбинации ISNUMBER() можно убрать, потому что LOOKUP, то бишь ПРОСМОТР() игнорирует ошибки, выдаваемые функцией SEARCH (ПОИСК).
Перенос данных дублирующихся строк в отдельные столбцы".
 
Да, сейчас все ОК)
Перенос данных дублирующихся строк в отдельные столбцы".
 
whateverlover, Взял обновленный файл, добавил Леонидовичам телефонов, но показываются не все. Взгляните).
Перенос данных дублирующихся строк в отдельные столбцы".
 
Цитата
whateverlover написал:
исправил
По-моему все же нет :)
Если добавить новый номер для Иванова, то он не появляется. Код Антона отрабатывает правильно.
Страницы: 1 2 3 4 5 6 7 8 9 10 11 ... 39 След.
Наверх