Sub GetComboList()
Dim lRow&, I&
Dim arr()
Dim iTmp
With Sheets("Список_НД")
  lRow = .Cells(.Rows.Count, 5).End(xlUp).Row
  'забираем в массив значения из 5го и 6го столбцов
  'если хотите 'Да' записывать в столбце 'H', то нужно расширить диапазон до 7го столбца
  'arr = .Range(.Cells(4, 5), .Cells(lRow, 7)).Value
  'если в каком-то другом столбце, то соответственно до номера этого столбца
  arr = .Range(.Cells(4, 5), .Cells(lRow, 6)).Value '
End With
With CreateObject("Scripting.Dictionary")
  For I = LBound(arr, 1) To UBound(arr, 1)
    'тогда и в массиве нужно указывать не второй 'столбец', а третий
    'If arr(I, 3) = "Да" Then
    'ну и так далее
    If arr(I, 2) = "Да" Then
      iTmp = .Item(arr(I, 1))
    End If
  Next
  arrList = Application.Transpose(.Keys)
End With
End Sub

Sub TableFrom1C()
Dim arr(), newArr()
Dim I&, J&, N&, K&
On Error Resume Next
Application.ScreenUpdating = False
With Worksheets("Лист1")
  arr = .Range("A2:G" & .Cells(.Rows.Count, "C").End(xlUp).Row).Value
End With
ReDim newArr(LBound(arr, 1) To UBound(arr, 1), 1 To 7)
For I = LBound(arr, 1) To UBound(arr, 1)
  If arr(I, 1) <> "" Then
    N = N + 1
    newArr(N, 1) = arr(I, 1)
    newArr(N, 2) = arr(I, 2)
    newArr(N, 3) = arr(I, 4)
    newArr(N, 4) = arr(I, 5)
    newArr(N, 5) = arr(I, 6)
    newArr(N, 6) = arr(I, 7)
    newArr(N, 7) = arr(I, 3)
    K = 7
  Else
    K = K + 1
    If K > UBound(newArr, 2) Then
      ReDim Preserve newArr(LBound(newArr, 1) To UBound(newArr, 1), LBound(newArr, 2) To K)
    End If
    newArr(N, K) = arr(I, 3)
  End If
Next
With Worksheets("Лист2")
  .Range("A2").CurrentRegion.ClearContents
  .Range("A1").Resize(N, UBound(newArr, 2)) = newArr
  .Activate
End With
Application.ScreenUpdating = True
End Sub

Private Sub UserForm_Initialize()
Dim s&, I&
Dim arr()
Dim iTmp
With Sheets("Список_НД")
  s = .Cells(.Rows.Count, 5).End(xlUp).Row
  arr = .Range(.Cells(4, 5), .Cells(s, 6)).Value
End With
With CreateObject("Scripting.Dictionary")
  For I = LBound(arr, 1) To UBound(arr, 1)
    If arr(I, 2) = "Да" Then
      iTmp = .Item(arr(I, 1))
    End If
  Next
  Me.ComboBox1.List = Application.Transpose(.Keys)
End With
Me.ComboBox1.MatchEntry = fmMatchEntryNone
End Sub

Sub Koniashka26()
Dim arr(), newArr()
Dim iKey, iTmp, arrTmp
Dim I&, J&, N&
On Error Resume Next
Application.ScreenUpdating = False
With Worksheets("Лист1")
  arr = .Range("A5:F" & .Cells(.Rows.Count, "A").End(xlUp).Row).Value
End With
With CreateObject("Scripting.Dictionary")
  For I = LBound(arr, 1) To UBound(arr, 1)
    iKey = Trim(arr(I, 3))
    If .Exists(iKey) Then
      arrTmp = .Item(iKey)
      arrTmp(1, 2) = arrTmp(1, 2) & vbCrLf & arr(I, 2)
      arrTmp(1, 5) = arrTmp(1, 5) + arr(I, 5)
      .Item(iKey) = arrTmp
    Else
      ReDim arrTmp(1 To 1, LBound(arr, 2) To UBound(arr, 2))
      For J = LBound(arr, 2) To UBound(arr, 2)
        arrTmp(1, J) = arr(I, J)
      Next
      .Add iKey, arrTmp
    End If
  Next
  ReDim newArr(1 To .Count, LBound(arr, 2) To UBound(arr, 2))
  For Each iKey In .Keys
    arrTmp = .Item(iKey)
    For I = LBound(arrTmp, 1) To UBound(arrTmp, 1)
      N = N + 1
      For J = LBound(arrTmp, 2) To UBound(arrTmp, 2)
        newArr(N, J) = arrTmp(1, J)
      Next
    Next
  Next
End With
With Worksheets("Лист2")
  .Range("A1").Resize(N, UBound(newArr, 2)) = newArr
  .Columns("A:F").WrapText = False
  .Activate
End With
Application.ScreenUpdating = True
End Sub

Sub Numbering()
Dim iCl As Range
Dim mCl As Range
Dim fNumber$
Application.ScreenUpdating = False
For Each iCl In Selection
  If iCl.MergeCells Then
    If Not IsEmpty(iCl) Then
      fNumber = Trim(CStr(iCl.Value))
      For Each mCl In iCl.MergeArea.Cells
        N = N + 1
        mCl.Offset(, 3) = fNumber & "." & N
      Next
    End If
  Else
    iCl.Offset(, 3) = Trim(CStr(iCl.Value)) & ".1"
  End If
  N = 0
Next
Application.ScreenUpdating = True
End Sub

Sub OPL_Count()
  Dim folderPath As String, fileName As String
  Dim iWb As Workbook
  Dim iSh As Worksheet
  Dim arr()
  Dim I&, oplCount&
  
  On Error Resume Next
  Application.ScreenUpdating = False
  ReDim arr(1 To 3, 1 To 1)
  ' Путь к папке
'  folderPath = "C:\Прайсы"
  folderPath = ThisWorkbook.Worksheets("Лист1").Range("E1") & Application.PathSeparator 'путь к апапке в ячейке 'E1'
  ' Получаем первый файл в папке
  fileName = Dir(folderPath & Application.PathSeparator & "*.xls*")

  ' Пока есть файлы в папке
  Do While fileName <> ""
    Set iWb = Application.Workbooks.Open(folderPath & fileName)
    If Not iWb Is Nothing Then
      For Each iSh In iWb.Worksheets
        oplCount = Application.WorksheetFunction.CountIf(iSh.UsedRange, "*" & ThisWorkbook.Worksheets("Лист1").Range("E2") & "*")
        If oplCount > 0 Then
          I = I + 1
          ReDim Preserve arr(1 To 3, 1 To I)
          arr(1, I) = iWb.Name
          arr(2, I) = iSh.Name
          arr(3, I) = oplCount
        End If
      Next
      iWb.Close False
    End If
    fileName = Dir()
  Loop
  With ThisWorkbook.Worksheets("Лист1")
    .Range("A1:C" & .Cells(.Rows.count, "A").End(xlUp).Row).ClearContents
    .Range("A1").Resize(I, 3) = Application.Transpose(arr)
    .Columns("A:C").EntireColumn.AutoFit
  End With
  Application.ScreenUpdating = True
  ' Выводим сообщение об успешном завершении
  MsgBox "Список файлов сформирован."
End Sub