let
    fRec = (Таблица as table, Ключ as text, Значение as text) as record   =>  
        Record.FromTable(
            Table.RenameColumns(
                Таблица,
                {
                    {Ключ, "Name"}, 
                    {Значение, "Value"}
                }
            )
        ),
    fAddCol = (Таблица as table, ИмяСтолбца as text, СтолбецСДатой as text, Запись as record, Ключ as text) as table =>
        Table.AddColumn(
            Таблица,
            ИмяСтолбца,
            each    if Record.Field(_, СтолбецСДатой) = List.Max(Table.Column(Таблица,СтолбецСДатой)) 
                    then Record.FieldOrDefault(
                            Запись,       
                            Text.From(Record.Field(_, Ключ)), 
                            null
                         ) 
                    else null, 
            Number.Type         
        ),
    Days =  fRec(#"Кол_дней сварщик", "Сварщик", "Количество дней"),
    Inches = fRec(#"Дюймов в день", "Сварщик", "Дюймов в день"), 
    Source = Стыки_диаметр_сварщик,
    Sort = Table.Sort(Source, {"Дата", Order.Ascending}),
    Group = Table.Group(Sort, "Сварщик", {"temp", 
                (t)=>   [   AddDays = fAddCol(t,"Кол-во дней", "Дата", Days, "Сварщик"),        
                            AddInches = fAddCol(AddDays,"Кол-во дюймов", "Дата", Inches, "Сварщик")
                        ][AddInches]        
                }
            ),
    Combine = Table.Combine(Group[temp])
in
    Combine